创建自定义Flux函数
Flux的功能语法允许您创建自定义函数。本指南将带您了解创建您自己的函数的基础知识。
函数定义语法
在Flux中定义函数的基本语法如下
// Basic function definition syntax
functionName = (functionParameters) => functionOperations
functionName
在您的Flux脚本中调用函数时使用的名称。
functionParameters
传递到函数中并在其操作中使用的一系列参数的逗号分隔列表。可以为每个参数定义参数默认值。
functionOperations
操作和函数，用于将输入操作为所需的输出。
基本函数示例
示例平方函数
// Function definition
square = (n) => n * n
// Function usage
> square(n:3)
9
示例乘法函数
// Function definition
multiply = (x, y) => x * y
// Function usage
> multiply(x: 2, y: 15)
30
在自定义函数中使用管道前数据
大多数Flux函数处理管道前数据。要处理管道前数据，函数的参数之一必须使用<-管道接收表达式捕获输入表。
在下面的示例中，tables参数被分配给<-表达式，它代表所有管道到函数中的数据。tables然后被管道传输到函数定义中的其他操作。
functionName = (tables=<-) => tables |> functionOperations
可管道传输函数示例
将行值乘以x
以下示例定义了一个multByX函数，它将输入表的每一行的_value列乘以x参数。它使用map()函数修改每个_value。
// Function definition
multByX = (tables=<-, x) => tables
|> map(fn: (r) => ({r with _value: r._value * x}))
// Function usage
from(bucket: "example-bucket")
|> range(start: -1m)
|> filter(fn: (r) => r._measurement == "mem" and r._field == "used_percent")
|> multByX(x: 2.0)
定义参数默认值
使用=赋值运算符为您函数定义中的函数参数分配默认值
functionName = (param1=defaultValue1, param2=defaultValue2) => functionOperation
默认值可以通过在函数调用中显式定义参数来覆盖。
具有默认值的示例函数
获取领导者列表
以下示例定义了一个leaderBoard函数，该函数返回按指定列中的值排序的有限记录数。它使用sort()函数按升序或降序排序记录。然后使用limit()函数从排序表中返回指定数量的记录。
// Function definition
leaderBoard = (tables=<-, limit=4, columns=["_value"], desc=true) => tables
|> sort(columns: columns, desc: desc)
|> limit(n: limit)
// Function usage
// Get the 4 highest scoring players
from(bucket: "example-bucket")
|> range(start: -1m)
|> filter(fn: (r) => r._measurement == "player-stats" and r._field == "total-points")
|> leaderBoard()
// Get the 10 shortest race times
from(bucket: "example-bucket")
|> range(start: -1m)
|> filter(fn: (r) => r._measurement == "race-times" and r._field == "elapsed-time")
|> leaderBoard(limit: 10, desc: false)
使用作用域变量定义函数
要创建具有函数作用域变量的自定义函数，请在块（{}）内放置您的函数操作和变量，并使用return语句返回特定变量。
functionName = (functionParameters) => {
exampleVar = "foo"
return exampleVar
}
具有作用域变量的示例函数
基于值返回警报级别
以下函数使用条件逻辑根据数值输入返回警报级别
alertLevel = (v) => {
level = if float(v: v) >= 90.0 then
"crit"
else if float(v: v) >= 80.0 then
"warn"
else if float(v: v) >= 65.0 then
"info"
else
"ok"
return level
}
alertLevel(v: 87.3)
// Returns "warn"
将十六进制颜色代码转换为名称
以下函数将十六进制（HEX）颜色代码转换为等效的HTML颜色名称。该函数使用Flux字典包创建包含十六进制代码及其对应名称的字典。
import "dict"
hexName = (hex) => {
hexNames = dict.fromList(
pairs: [
{key: "#00ffff", value: "Aqua"},
{key: "#000000", value: "Black"},
{key: "#0000ff", value: "Blue"},
{key: "#ff00ff", value: "Fuchsia"},
{key: "#808080", value: "Gray"},
{key: "#008000", value: "Green"},
{key: "#00ff00", value: "Lime"},
{key: "#800000", value: "Maroon"},
{key: "#000080", value: "Navy"},
{key: "#808000", value: "Olive"},
{key: "#800080", value: "Purple"},
{key: "#ff0000", value: "Red"},
{key: "#c0c0c0", value: "Silver"},
{key: "#008080", value: "Teal"},
{key: "#ffffff", value: "White"},
{key: "#ffff00", value: "Yellow"},
],
)
name = dict.get(dict: hexNames, key: hex, default: "No known name")
return name
}
hexName(hex: "#000000")
// Returns "Black"
hexName(hex: "#8b8b8b")
// Returns "No known name"
这个页面有帮助吗？
感谢您的反馈！